home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
SuperHack
/
SuperHack CD.bin
/
SCRIPTZ
/
PAQUI.ZIP
/
aliases.ini
next >
Wrap
INI File
|
1996-12-13
|
25KB
|
581 lines
[Aliases]
n0=pn notice $$1 ½^P-A-Q-U-I^ PrivNotice╗ *2
n1=op mode # +ooo $$1 $2 $3
n2=dop mode # -ooo $$1 $2 $3
n3=j join #$$1 *2
n4=p part #
n5=t topic # *1
n6=n names #$$1
n7=w whois $$1
n8=k kick # $$1
n9=q query $$1
n10=hop part # | join #$$1
n11=send dcc send $1 $2
n12=chat dcc chat $1
n13=;½ Li0n ╗ Aliases, function keys and identifiers ( in no particular order =)
n14=/test /titlebar $tbar(test,test.tb) | /.timer 21 1 /titlebar $!tbar(test) | /.timer 1 30 /titlebar %default.tb
n15=/song /titlebar $tbar(song,song.tb) | /.timer985 0 3 /titlebar $!tbar(song)
n16=aremini remini *1
n17=join {
n18= if ($2 != $null) { set %chankey. $+ $1 $2 }
n19= join *1
n20=}
n21=rtoken {
n22= if ($1 == $null) || ($2 == $null) || ($3 == $null) { return Error }
n23= if ($1 > $token(0,$2,*3)) { return }
n24= set %counter 1
n25= set %return *3
n26= :begin
n27= if (%counter < $1) {
n28= %token = $token(1,$2,%return) | %len = $len(%token) + 2
n29= %return = $mid(%len,$len(%return),%return)
n30= inc %counter
n31= goto begin
n32= }
n33= return %return
n34= unset %return %counter
n35=}
n36=/joinchannels {
n37= set %counter 1
n38= if (%set.rejoin != ON) && (%joinfile == join.txt) { halt }
n39= :begin
n40= set %channel $read -l $+ %counter [ $mircdir [ $+ [ %joinfile ] ] ]
n41= if (%channel != $null) {
n42= join %channel
n43= inc %counter
n44= goto begin
n45= }
n46= unset %counter %channel
n47= set %joinfile join.txt
n48=}
n49=perc {
n50= if $2 == $null { return Syntax error }
n51= if ($3 == bar) {
n52= if ($4 != $null) {
n53= set %scale $4
n54= }
n55= else { set %scale 20 }
n56= }
n57= %x = $1 * 100 | %x1 = $1 * %scale
n58= if ($2 != 1) { %rest = $2 / 2 } | else { %rest = 1 }
n59= %y = %x / $2 | %y1 = %x1 / $2
n60= %z = %x % $2 | %z1 = %x1 % $2
n61= if (%z > %rest) { inc %y }
n62= if (%z1 > %rest) { inc %y1 }
n63= %y2 = %scale - %y1
n64= if (%y1 > 0) && (%y2 > 0) { set %bar $chr(91) $+ $str(%y1,$chr(35)) $+ $str(%y2,=) $+ $chr(93) }
n65= elseif (%y1 > 0) && (%y2 == 0) { set %bar $chr(91) $+ $str(%y1,$chr(35)) $+ $chr(93) }
n66= else { set %bar $chr(91) $+ $str(%y2,=) $+ $chr(93) }
n67= if ($3 == bar) { set %return %bar %y $+ % } | else { set %return %y $+ % }
n68= unset %bar %x %x1 %rest %y %y1 %z %z1 %y2
n69= return %return
n70=}
n71=chanstats {
n72= msg # Ops on # : $opnick(0,#) $perc($opnick(0,#),$nick(0,#),bar)
n73= msg # NonOps on # : $nopnick(0,#) $perc($nopnick(0,#),$nick(0,#),bar)
n74=}
n75=/cban {
n76= if ($me isop #) {
n77= aecho Clearing ban list on # | /unset %unban %bans | /.enable #cban | mode # b
n78= }
n79= else { aecho You are not channel operator or are not on a channel currently }
n80=}
n81=/quit {
n82= set %joinfile autojoin.txt
n83= write -c $mircdir $+ join.txt
n84= quit *1
n85=}
n86=switch {
n87= set %total $len(*1)
n88= set %counter 2
n89= set %line $mid(1,1,*1)
n90= :begin
n91= if (%counter <= %total) {
n92= set %char $mid(%counter,1,*1)
n93= set %line %line $+ $k(3,7) $+ %char $+ $k(1,7)
n94= inc %counter
n95= set %char $mid(%counter,1,*1)
n96= if (%char != $null) {
n97= if %char != $chr(32) { set %line %line $+ %char }
n98= else { set %line %line $+ á }
n99= }
n100= inc %counter
n101= goto begin
n102= }
n103= return %line
n104=}
n105=ctcp {
n106= if (# isin $1) { set %ctcp.channel $ctime }
n107= else { set %ctcp. $+ $1 $ctime }
n108= if ($2 == ping) {
n109= raw -q PRIVMSG $$1 : $+ $$2 $ctime $+
n110= echo 4 $active $chr(91) $+ $1 PING $+ $chr(93)
n111= goto end
n112= }
n113= if ($3 == $null || $1 == $3) {
n114= echo 4 $active $chr(91) $+ $1 $upper($2) $+ $chr(93)
n115= raw -q PRIVMSG $$1 : $+ $$2 $+
n116= }
n117= else {
n118= echo 4 $active $chr(91) $+ $1 $upper($2) *3 $+ $chr(93)
n119= raw -q PRIVMSG $$1 : $+ $$2 *3 $+
n120= }
n121= :end
n122=}
n123=ping {
n124= if ($1 == $null) {
n125= echo 4 $active $chr(91) $+ # PING $+ $chr(93)
n126= raw -q PRIVMSG # : $+ PING $ctime $+
n127= }
n128= else {
n129= echo 4 $active $chr(91) $+ $1 PING $+ $chr(93)
n130= raw -q PRIVMSG $$1 : $+ PING $ctime $+
n131= }
n132=}
n133=ver {
n134= if ($1 == $null) {
n135= set %ctcp.channel $ctime
n136= echo 4 $active $chr(91) $+ # VERSION $+ $chr(93)
n137= raw -q PRIVMSG # :VERSION
n138= }
n139= else {
n140= set %ctcp. $+ $1 $ctime
n141= echo 4 $active $chr(91) $+ $1 VERSION $+ $chr(93)
n142= raw -q PRIVMSG $$1 :VERSION
n143= }
n144=}
n145=cycle set %tempkey $chan(#).key | raw -q PART # | raw -q JOIN # %tempkey | unset %tempkey
n146=wall .onotice \\' [Ops on # $+ ] *1 | echo 4 # - WallOp - \\' [Ops on # $+ ] *1
n147=ome .onotice \\' [Ops on # $+ ] * $me *1 | echo 4 # - WallOp - \\' [Ops on # $+ ] * $me *1
n148=ww whowas $$1
n149=pingout /timer100 0 30 /raw -q pong $server $server
n150=clones {
n151= echo 4 # ½ Li0n ╗ Starting Clone Scan...
n152= set %chanclones 0
n153= set %counter 1
n154= set %total $nick(0,#)
n155= :init
n156= if (%counter <= %total) {
n157= set %site $remove($address($nick(%counter,#),2),*!*@)
n158= set %clone $readini $mircdir $+ scan.ini x %site
n159= if ((%clone != $null) && (%site !isin %s)) { writeini $mircdir $+ scan.ini x %site %clone $nick(%counter,#) | %s = [ %s ] %site }
n160= elseif (%clone != $null) { writeini $mircdir $+ scan.ini x %site %clone $nick(%counter,#) }
n161= else { writeini $mircdir $+ scan.ini x %site $nick(%counter,#) }
n162= inc %counter
n163= goto init
n164= }
n165= set %counter 1
n166= set %total $token(0,32,%s)
n167= set %chanclones 0
n168= :display
n169= if (%counter <= %total) {
n170= set %clones $readini $mircdir $+ scan.ini x $token(%counter,32,%s)
n171= inc %chanclones $token(0,32,%clones)
n172= echo 4 # ½ Li0n ╗ $token(0,32,%clones) clones from $token(%counter,32,%s) : %clones
n173= inc %counter
n174= goto display
n175= }
n176= unset %clones
n177= if (%chanclones > 0) { echo 4 # ½ ^P-A-Q-U-I^ ╗ Total Clones on # : %chanclones }
n178= else { echo 4 # ½ ^P-A-Q-U-I^ ╗ No clones detected }
n179= :unset
n180= unset %clone %counter %chanclones %site %total %s
n181= remini $mircdir $+ scan.ini x
n182=}
n183=add {
n184= if ($token(0,32,*1) < 3) { aecho Syntax : /add #channel address options(o/f/n/b) [note] | halt }
n185= if ($3 != o) && ($3 != f) && ($3 != n) && ($3 != b) { aecho Syntax : /add #channel address options(o/f/n/b) [note] | halt }
n186= writeini $mircdir $+ userinfo.ini $1 Unknown $2 $3 $fulldate *4
n187= if ($3 == o) || ($3 == f) { auser 20 $1 }
n188= else { auser 10 $1 }
n189=}
n190=mailoptions {
n191= set %autoget $?="Autoget mail on connect? (Y/N)"
n192= if %autoget == $null { set %autoget Y }
n193= set %forgetpass $?="Forget password? (Y/N)"
n194= if (%forgetpass == $null) { set %forgetpass Y }
n195= if (%forgetpass == Y) { unset %pop.pass }
n196= echo 4 $active Options are set : Autoget mail on connect : %autoget and Forget Password : %forgetpass
n197=}
n198=mailcheck {
n199= if (%pop.host == $null) || ($longip(%pop.host) == $null) {
n200= set %pop.host $$?="What host to use (ip-NUMBER)"
n201= if ($longip(%pop.host) == $null) { aecho Please use the numerical ip. Look in your status window for this number | /dns %pop.host | halt }
n202= }
n203= if (%pop.user == $null) { set %pop.user $$?="Username?" }
n204= if (%pop.pass == $null) { set %pop.pass $$?="Password?" }
n205= .creq auto
n206= .enable #mail
n207= set %mail.n $me
n208= raw -q privmsg $me : $+ $chr(1) $+ DCC CHAT CHAT $longip(%pop.host) 110 $+ $chr(1)
n209=}
n210=seemail {
n211= if (%mail.win == $null) { echo 4 $active Not connected to mail server | halt }
n212= if ($1 == $null) { echo 4 %mail.win *** Syntax : /seemail <message-number $chr(124) all> }
n213= elseif ($1 == all) { set %mail.counter 1 | getmail | .timer653 0 5 getmail }
n214= else { msg = $+ %mail.n RETR $1 }
n215=}
n216=getmail {
n217= if (%mail.counter <= %mail.messages) { msg = $+ %mail.n RETR %mail.counter | inc %mail.counter }
n218= else { .timer653 off | unset %mail.counter }
n219=}
n220=quitmail { msg = $+ %mail.n quit }
n221=/joinchannels {
n222= set %counter 1
n223= :begin
n224= set %channel $read -l $+ %counter $mircdir $+ channels.rl
n225= if (%channel != $null) {
n226= join %channel
n227= inc %counter
n228= goto begin
n229= }
n230= unset %counter %channel
n231=}
n232=/msjit {
n233= if ($1 == $null) { aecho Syntax : /msjit <mask> <number of days> [channel] <reason> | halt }
n234= if ($2 !isnum) { aecho Syntax : /msjit <mask> <number of days> [channel] <reason> | halt }
n235= if (@ isin $1) { set %smask $1 | set %snick Unknown }
n236= else { set %smask $address($1,2) | set %snick $1 }
n237= if ($chr($asc(#)) isin $3 ) { set %chan $3 | set %sreason *4 }
n238= else { set %chan # | set %sreason *3 }
n239= set %days $2
n240= sjit %chan
n241=}
n242=/rmsjit {
n243= if ($1 == $null) { aecho Syntax : /msjit <mask> [channel] | halt }
n244= if ($2 == $null) { set %chan # }
n245= else { set %chan $2 }
n246= if (@ isin $1) {
n247= set %entry $1
n248= .ruser 10 %entry
n249= remini $mircdir $+ userinfo.txt %chan %entry
n250= aecho Entry %entry removed from Sjit list on %chan
n251= mode %chan -b %entry
n252= }
n253= else {
n254= set %entry $maddress($address($1,0))
n255= .ruser 10 %entry
n256= remini $mircdir $+ userinfo.txt %chan %entry
n257= aecho Entry %entry removed from Sjit list on %chan
n258= mode %chan -b %entry
n259= }
n260= unset %entry %chan
n261=}
n262=/filterkick {
n263= if ($gettok(*1,0,32) < 1) { aecho Syntax : /filterkick <banmask> [#channel] [kick message] }
n264= set %banmask $1
n265= if ($2 == $null) {
n266= if ($me !isop #) { aecho Error : not on a channel, or not chanop | aecho Syntax : /filterkick <banmask> [#channel] [kick message] }
n267= else { set %channel # }
n268= }
n269= else {
n270= if ($me !isop $2) { aecho Error : not on a channel, or not chanop | aecho Syntax : /filterkick <banmask> [#channel] [kick message] }
n271= else { set %channel $2 }
n272= }
n273= if ($3 == $null) { set %kickmessage ½ Li0n ╗ Filter Kick of %banmask }
n274= else { set %kickmessage *3 }
n275= set %total $ial(%banmask,0)
n276= %counter = 1
n277= :check
n278= if (%counter <= %total) {
n279= set %kicknick $ial(%banmask,%counter).nick
n280= if (%kicknick ison %channel) && ($level($ial(%banmask,%counter)) < 20) {
n281= kick %channel %kicknick %kickmessage
n282= }
n283= inc %counter
n284= goto check
n285= }
n286= :end
n287= unset %channel %total %counter %banmask %kickmessage %kicknick
n288=}
n289=/sjit {
n290= %timeout = %days * 86400
n291= %timeout = %timeout + $ctime
n292= writeini $mircdir $+ userinfo.ini $1 %smask %snick s %timeout $token($token(2,47,$date),47,%month) $token(1,47,$date) $+ : %sreason
n293= write $mircdir $+ ban.log %timeout $1 %smask
n294= .auser 10 %smask
n295= aecho Sjit list entry added for: %smask on $1 for %days days. Reason: %sreason
n296= mode $1 +b %smask
n297= filterkick %smask $1 $token($token(2,47,$date),47,%month) $token(1,47,$date) $+ : %sreason
n298= unset %smask %sreason %timeout %days %snick
n299=}
n300=/expire {
n301= set %counter 1
n302= :begin
n303= set %line $read -l $+ %counter $mircdir $+ bans.log
n304= if (%line != $null) {
n305= set %exptime $gettok(%line,1,32)
n306= if ($ctime > %exptime) {
n307= write -ds $+ $gettok(%line,1,32) $mircdir $+ bans.ini
n308= remini $mircdir $+ userinfo.ini $gettok(%line,2,32) $gettok(%line,3,32)
n309= .ruser 10 $gettok(%line,3,32)
n310= goto begin
n311= }
n312= inc %counter
n313= goto begin
n314= }
n315= unset %line %counter
n316=}
n317=/aecho echo 4 -a ½ Li0n ╗ *1
n318=atime {
n319= set %hours $token(1,58,$time)
n320= if (%hours > 12) { dec %hours 12 | /set %sub pm }
n321= elseif (%hours == 12) { set %sub pm }
n322= elseif (%hours == 0) { set %hours 12 | /set %sub am }
n323= else { set %sub am }
n324= return %hours $+ : $+ $token(2,58,$time) $+ %sub
n325=}
n326=/msgreview {
n327= echo 4 -s -[ ^P-A-Q-U-I^ ]- Message review
n328= if (%msg5 != $null) { echo 4 -s %msg5 }
n329= if (%msg4 != $null) { echo 4 -s %msg4 }
n330= if (%msg3 != $null) { echo 4 -s %msg3 }
n331= if (%msg2 != $null) { echo 4 -s %msg2 }
n332= if (%msg1 != $null) { echo 4 -s %msg1 }
n333= else { echo 4 -s -[ ^P-A-Q-U-I^ ]- No Messages }
n334=}
n335=/rctcp {
n336= if ($3 == $null) {
n337= raw -q PRIVMSG $$1 : $+ $$2 $+
n338= }
n339= else { raw -q PRIVMSG $$1 : $+ $$2 *3 $+ }
n340=}
n341=/gone {
n342= ame is away - $? - Messages are logged
n343= away since 3-7 $+ $atime $+ - - $+ $$!
n344= %msg = 0
n345= write -c $mircdir $+ away.log
n346= .enable #AwayMsgLog
n347=}
n348=back {
n349= ame is back -- I know.. who cares.
n350= away
n351= .disable #AwayMsgLog
n352= if (%msg == 0) { set %msg no }
n353= aecho You have %msg message(s) waiting
n354= unset %msg
n355=}
n356=xlist {
n357= set %xdcc.win -[á^P-A-Q-U-I^ v2.0á]-áXDCCáWindow
n358= query %xdcc.win
n359= set %total $readini $mircdir $+ xdcc.ini main total
n360= echo 4 %xdcc.win á
n361= if (%total == $null) { echo 4 %xdcc.win No packets offered | halt }
n362= set %counter 1
n363= :begin
n364= if (%counter <= %total) {
n365= set %packet $readini $mircdir $+ xdcc.ini main %counter
n366= echo 4 %xdcc.win $+ $chr(35) $+ %counter $+ [ $readini $mircdir $+ xdcc.ini %packet dl ] $+ x $chr(91) $+ $+ [ $readini $mircdir $+ xdcc.ini %packet size ] $+ B $+ $+ $chr(93) $readini $mircdir $+ xdcc.ini %packet name
n367= inc %counter
n368= goto begin
n369= }
n370= unset %counter %xdcc.win %total %packet
n371=}
n372=xadd {
n373= set %total $readini $mircdir $+ xdcc.ini main total
n374= set %packet $r(a,z) $+ $r(a,z) $+ $r(a,z) $+ $r(a,z) $+ $r(a,z) $+ $r(a,z)
n375= set %name $$?="Give a description for the packet"
n376= set %path $?="Give a full pathname for the packet"
n377= :begin
n378= if ($exists(%path) == $false) {
n379= set %path $?="Give a full pathname for the packet"
n380= goto begin
n381= }
n382= set %size $lof(%path)
n383= if (%size < 1000) { set %size [ %size ] $+ B }
n384= elseif (%size > 1000000) {
n385= %m = %size / 1000000 | %k = %size % 1000000
n386= %k = %k / 100000
n387= set %size [ %m ] $+ . $+ [ %k ] $+ M
n388= }
n389= else { %k = %size / 1000 | set %size [ %k ] $+ k }
n390= unset %k %m
n391= writeini $mircdir $+ xdcc.ini %packet path %path
n392= writeini $mircdir $+ xdcc.ini %packet name %name
n393= writeini $mircdir $+ xdcc.ini %packet size %size
n394= writeini $mircdir $+ xdcc.ini %packet dl 0
n395= inc %total
n396= writeini $mircdir $+ xdcc.ini main total %total
n397= writeini $mircdir $+ xdcc.ini main %total %packet
n398= aecho Packet $+ $chr(35) $+ %total $+ ' $+ %name $+ ' has been added
n399= unset %packet %path %name %size %total
n400=}
n401=/xdel {
n402= if ($1 == $null) { set %packet $$?="What packet number? (/xlist for list)" }
n403= else { set %packet $1 }
n404= set %total $readini $mircdir $+ xdcc.ini main total
n405= if (%packet !isnum) || (%packet > %total) { aecho XDCC -- incorrect packet number. Type /xlist for a list | halt }
n406= remini $mircdir $+ xdcc.ini [ $readini $mircdir $+ xdcc.ini main %packet ]
n407= set %counter %packet
n408= :begin
n409= if (%counter < %total) {
n410= %getpack = %counter + 1
n411= set %packname $readini $mircdir $+ xdcc.ini main %getpack
n412= writeini $mircdir $+ xdcc.ini main %counter %packname
n413= inc %counter
n414= goto begin
n415= }
n416= remini $mircdir $+ xdcc.ini main %counter
n417= dec %total
n418= writeini $mircdir $+ xdcc.ini main total %total
n419= unset %packet %counter %packname %getpack
n420=}
n421=/xoffer {
n422= set %total $readini $mircdir $+ xdcc.ini main total
n423= if (%total == $null) { aecho No packets offered | halt }
n424= set %counter 1
n425= msg # -[ Li0n ]- XDCC OFFER ** %total pack(s) offered **
n426= msg # -[ Li0n ]- Type /ctcp $me XDCC SEND #n to receive
n427= :begin
n428= if (%counter <= %total) {
n429= set %packet $readini $mircdir $+ xdcc.ini main %counter
n430= msg # $+ $chr(35) $+ %counter $+ áá [ $readini $mircdir $+ xdcc.ini %packet dl ] $+ x $chr(91) $+ $+ [ $readini $mircdir $+ xdcc.ini %packet size ] $+ B $+ $+ $chr(93) $readini $mircdir $+ xdcc.ini %packet name
n431= inc %counter
n432= goto begin
n433= }
n434= if (%xdccmessage != $null) { msg # -[ Li0n ]- %xdccmessage }
n435= unset %counter %total %packet
n436=}
n437=/chanstat {
n438= if (# == $null) { aecho Current window is not a channel | halt }
n439= set %status -[á^P-A-Q-U-I^á]-á $+ # $+ ástatus
n440= query %status
n441= clear %status
n442= if (%clone.all == on) { echo 4 %status * Global Clone Protection : on }
n443= elseif (%clone. [ $+ [ # ] ] == on) { echo 4 %status * Clone Protection for # : on }
n444= else { echo 4 %status * Clone Protection for # : off }
n445= if (%serverop.all == on) { echo 4 %status * Global Serverop Protection : on }
n446= elseif (%serverop. [ $+ [ # ] ] == on) { echo 4 %status * Serverop Protection for # : on }
n447= else { echo 4 %status * Serverop Protection for # : off }
n448= if (%nick.all == on) { echo 4 %status * Global Nick Protection : on }
n449= elseif (%nick. [ $+ [ # ] ] == on) { echo 4 %status * Nick Protection for # : on }
n450= else { echo 4 %status * Nick Protection for # : off }
n451= if (%deop.all == on) { echo 4 %status * Global Reopping of Ops : on }
n452= elseif (%deop. [ $+ [ # ] ] == on) { echo 4 %status * Reopping of Ops for # : on }
n453= else { echo 4 %status * Reopping of Ops for # : off }
n454= if (%restrict.all == on) { echo 4 %status * Global Restriction of Ops : on }
n455= elseif (%restrict. [ $+ [ # ] ] == on) { echo 4 %status * Restriction of Ops for # : on }
n456= else { echo 4 %status * Restriction of Ops for # : off }
n457= if (%repeat.all == on) { echo 4 %status * Global Repeat Kick : on }
n458= elseif (%repeat. [ $+ [ # ] ] == on) { echo 4 %status * Repeat Kick for # : on }
n459= else { echo 4 %status * Repeat Kick for # : off }
n460= if (%enfmode. [ $+ [ # ] ] != $null) { echo 4 %status * Enforcing modes on # : %enfmode. [ $+ [ # ] ] }
n461= else { echo 4 %status * Not enforcing modes on # }
n462= unset %status
n463=}
n464=status {
n465= set %status -[á^P-A-Q-U-I^á]-ástatus
n466= query %status
n467= clear %status
n468= if (%set.whois == on) { echo 4 %status * Show whois in active window : on }
n469= else { echo 4 %status * Show whois in active window : off }
n470= if (%set.msg == on) { echo 4 %status * Show new message in active window : on }
n471= else { echo 4 %status * Show new message in active window : off }
n472= if (%set.rejoin == on) { echo 4 %status * Rejoin channels after a hard quit : on }
n473= else { echo 4 %status * Rejoin channels after a hard quit : off }
n474= echo 4 %status * Default enforcing mode : %set.defmode
n475= echo 4 %status * AutoAway is %set.aaway $+ , and AutoBack is %set.aback
n476= echo 4 %status * AutoAway is triggered after %set.aaway.idle secs of idleness, and is checked every %set.aaway.check secs
n477= echo 4 %status * Person is kicked if he repeats within %set.rp secs
n478= echo 4 %status * Person is kicked for nickflooding when changing nick %set.nick times within %set.ntimer secs
n479= echo 4 %status * Clone protection is triggered after %set.clone clients from the same address have joined the channel
n480= if (%set.ck == ON) { echo 4 %status * All clones are kicked when detected }
n481= else { echo 4 %status * You are alerted of clones and can use F4 to kick }
n482= if (%xdcc == on) { echo 4 %status * XDCC server is : on }
n483= else { echo 4 %status * XDCC server is : off }
n484= if (%xdccmessage != $null) { echo 4 %status * XDCC messageline is : %xdccmessage }
n485= else { echo 4 %status * No XDCC messageline set }
n486= unset %status
n487=}
n488=/autoaway {
n489= if (%set.aaway == ON) && ($away != $true) {
n490= if ($idle > %set.aaway.idle) {
n491= away Automatically set away at $atime -- Messages are being logged
n492= ame has automatically been set away -- Messages are being logged
n493= set %start $ctime
n494= }
n495= }
n496= elseif (%set.aback == ON) && ($away == $true) {
n497= if ($idle < %set.aaway.idle) {
n498= away
n499= set %awaytime $ctime - %start
n500= ame has automatically been set back -- away for $duration(%awaytime)
n501= unset %start %awaytime
n502= }
n503= }
n504=}
n505=/li0n {
n506= echo 4 -s *****************************************************************************************************
n507= echo 4 -s Welcome to -^P-A-Q-U-I^ v.2.0 for mIRC 4.7- You are connected to $server
n508= echo 4 -s *****************************************************************************************************
n509= echo 4 -s -[ ^P-A-Q-U-I^ v2.0 ]- Released 9 December 1996
n510= echo 4 -s -[ ^P-A-Q-U-I^ v2.0 ]- by ^P-A-Q-U-I^
n511= echo 4 -s *****************************************************************************************************
n512=}
n513=/lhelp {
n514= set %help -[á^P-A-Q-U-I^ v2.0á]-áHelpáWindow
n515= if ($1 == $null) {
n516= query %help
n517= echo 4 %help á
n518= echo 4 %help -[ ^P-A-Q-U-I^ v2.0 ]- Main Help Menu
n519= echo 4 %help á
n520= echo 4 %help Topic -- Description
n521= echo 4 %help á
n522= echo 4 %help 1. -- Channel/Status Popup
n523= echo 4 %help 2. -- Nickname Popup
n524= echo 4 %help 3. -- Aliases
n525= echo 4 %help 4. -- Function keys
n526= echo 4 %help 5. -- Extra Identifiers
n527= echo 4 %help 6. -- Miscellaneous
n528= echo 4 %help 7. -- Trouble shooting
n529= echo 4 %help á
n530= echo 4 %help Use /Lhelp number to get further help
n531= }
n532= elseif ($1 isnum) {
n533= if ($1 > 7) { aecho No help availably on that | halt }
n534= else { play -ct $+ $1 $me $mircdir $+ li0n.snt 200 }
n535= }
n536= else {
n537= %exist = $readini $mircdir $+ li0n.snt main $1
n538= if (%exist != $null) { play -ct $+ $1 $me $mircdir $+ li0n.snt 200 }
n539= else { aecho No help available on that }
n540= }
n541=}
n542=/thelp /titlebar $tbar(main,main.tb) | /.timer985 0 7 /titlebar $!tbar(main)
n543=stat {
n544= write -c $mircdir $+ chanstat.tb
n545= set %counter 1
n546= set %total $chan(0)
n547= :begin
n548= if (%counter <= %total) {
n549= write $mircdir $+ chanstat.tb Stats for $chan(%counter) : Total $chr(36) $+ nick(0, $+ $chan(%counter) $+ ) Ops $chr(36) $+ opnick(0, $+ $chan(%counter) $+ )
n550= inc %counter
n551= goto begin
n552= }
n553= write $mircdir $+ chanstat.tb * Press sF12 to stop the Channel Statistic messages
n554= titlebar $tbar(chanstat,chanstat.tb) | /.timer985 0 7 /titlebar $!tbar(chanstat)
n555=}
n556=tbar {
n557= if ($1 == $null) { return Error }
n558= if ($2 == $null) {
n559= if (%tblines. [ $+ [ $1 ] ] == $null) { return Error.. incorrect name }
n560= }
n561= else {
n562= if ($exists($2) == $true) { set %tbfile. $+ $1 $2 | set %tblines. $+ $1 $lines($2) | set %tbcline. $+ $1 0 }
n563= else { return Incorrect filename }
n564= }
n565= inc %tbcline. $+ $1
n566= if (%tbcline. [ $+ [ $1 ] ] > %tblines. [ $+ [ $1 ] ]) { set %tbcline. $+ $1 1 }
n567= return $read -l $+ %tbcline. [ $+ [ $1 ] ] %tbfile. [ $+ [ $1 ] ]
n568=}
n569=/f2 /lhelp
n570=/f3 /mailcheck
n571=/f4 if (%clonesite != $null) { /filterkick %clonesite %clonechan | unset %clonesite %clonechan } | else { aecho No clones to kick }
n572=/f5 /chanstat
n573=/f6 /stat
n574=/f8 /msgreview
n575=/f9 /ignore -pu60 * | /set %MSGFLOOD ON
n576=/f11 /song
n577=/f12 /thelp
n578=/sf12 /.timer985 off | /titlebar %default.tb